Macros

Sugestões de macros úteis para sacerdotes.

Atenção

Note que diversas macros aqui usam a tecla shift como modificador. Se você quiser usar os atalhos shift-1 a shift-6, você precisa remover os atalhos de “página de ação”. Abra a opção Teclas de Atalho, seção Barra de ações, selecione as opções Página de ação de 1 a 6, e em cada uma clique em cima da tecla definida (shift-1, shift-2, etc.) e depois no botão Desvincular tecla.

Macros mouseover

Macro simples, lançando uma cura em uma pessoa, ao passar o mouse em cima dela. Também funciona se a pessoa a ser curada for seu alvo. Troque o nome da cura para o nome que for usar (Renovar, Cura Célere, etc.)

#showtooltip
/cast [@mouseover,help,nodead][] Cura

Para ter uma forma rápida de curar a você mesmo, você pode acrescentar uma tecla modificadora. Por exemplo, a macro abaixo é igual à anterior, mas usando a tecla shift a cura é lançada em você mesmo:

#showtooltip
/cast [mod:shift,@player][@mouseover,help,nodead][] Cura

Note que o uso de teclas modificadoras (no caso, shift) vai funcionar melhor se a tecla vinculada à essa macro não usar modificadores. Por exemplo: digamos que você colocou essa macro na sua barra de botões, num botão vinculado à tecla 2. Passando o mouse sobre um aliado e apertando 2 a cura vai para ele; apertando shift-2 a cura vai para você. Mas se você vincular a combinação de teclas alt-2 à essa macro, do jeito que ela está escrita não vai sair cura para você se você apertar alt-shift-2.

Você também pode substituir shift por outras teclas modificadoras, mudando o parâmetro mod:shift nas macros para mod:alt ou mod:ctrl.

Ao jogar como Sombra é útil ter algumas macros mouseover para te ajudar a aplicar dots em outros inimigos sem trocar de alvo. A macro abaixo aplica Palavra Sombria: Dor no seu alvo, ou se estiver passando o mouse sobre um inimigo ou sobre o nameplate dele (a plaquinha com nome e barra de saúde acima do inimigo), PS:D irá para ele ao invés do alvo atual.

#showtooltip
/cast [@mouseover,harm,nodead][] Palavra Sombria: Dor

Não esqueça de fazer uma macro para purificar (“dispelar”) também. Se for jogar como Disciplina ou Sagrado, use essa macro abaixo: ela lança Purificar em um aliado, em você mesmo usando shift, ou Dissipar Magia em um inimigo.

#showtooltip
/cast [mod:shift,@player][@mouseover,help,nodead][help,nodead] Purificar; Dissipar Magia

Na especialização de sombra, use esta outra macro no lugar:

#showtooltip
/cast [mod:shift,@player][@mouseover,help,nodead][help,nodead] Purificar Doença; Dissipar Magia

Se quiser uma macro com mouseover para lançar Seta Caótica nos inimigos, tem um detalhe: como esse feitiço substitui outro quando você muda de forma, chamar ele pelo nome na macro não funciona. Você tem que usar Erupção do Caos na macro para poder lançar Seta Caótica. A macro abaixo deixa você lançar a Seta num inimigo passando o mouse sobre o quadro dele, ou no seu alvo, apesar de estar com o nome de Erupção:

#showtooltip
/cast [@mouseover,harm,nodead][] Erupção do Caos

Curando ou atacando na mesma macro

Para economizar teclas, você pode fazer uma macro que lance uma cura se estiver com o mouse sobre o quadro (frame) da pessoa ou a pessoa no alvo, ou em você mesmo com shift, ou se nenhuma duas coisas for verdade mas estiver com um inimigo no alvo, então lança um ataque. A macro abaixo usa Recomposição Sombria nos dois primeiros casos, ou Punição em um inimigo:

#showtooltip
/cast [mod:shift,@player][@mouseover,help,nodead][help,nodead] Recomposição Sombria; Punição

Pena angelical

A macro abaixo facilita o uso do talento Pena Angelical; a pena vai ser colocada diretamente aos seus pés, afetando você imediatamente, sem precisar clicar no chão.

#showtooltip
/cast [@player] Pena Angelical
/stopspelltarget

O único problema é que desse jeito você não pode mais usar a pena para um aliado, ou mesmo colocando a pena no chão para usar depois (isso é bem útil em alguns momentos, inclusive PvP). Para esses casos, você pode usar outra tecla para o talento sem macro, ou então usar esta macro abaixo: se for usada sem shift, ela aplica a pena direto em você, se usada com shift, ela funciona como antes (aparece a retícula verde para clicar no chão).

#showtooltip
/cast [nomod,@player] Pena Angelical; [mod:shift] Pena Angelical
/stopspelltarget [nomod]

Penitência

Esta macro serve para sacerdotes Disciplina curarem com Penitência ao passar o mouse em um aliado, ou atacar com Penitência no alvo atual, ou mesmo curar com Penitência no alvo atual se o alvo for um aliado:

#showtooltip
/cast [@mouseover,help,nodead][] Penitência

E por falar nisso, pode ser que, na pressa em usar Palavra de Poder: Escudo em um aliado, você acabe cancelando a canalização do Penitência. Se quiser uma macro para evitar isto, use esta abaixo – ela cancela o uso de Palavra de Poder: Escudo se você ainda estiver canalizando Penitência.

#showtooltip Palavra de Poder: Escudo
/stopmacro [channeling:Penitência]
/cast [@mouseover,help,nodead][] Palavra de Poder: Escudo

Macros para foco

“Foco” é uma espécie de alvo secundário. Ele aparece na sua tela como um outro alvo, só que menor. A utilidade de ter alguém no foco é poder “ficar de olho” em um inimigo ou aliado específico, enquanto você muda de alvo normalmente.

Exemplo mostrando o alvo e o foco. Ao mudar de alvo o foco permanece o mesmo, até ser alterado ou sair do seu alcance.

Por exemplo: em lutas de raid onde haja mais de um chefe, você pode colocar o principal no foco, assim pode trocar de alvo para os outros chefes ou adds, e rapidamente retornar a ele, ou até mesmo lançar ataques no foco sem mudar de alvo.

Para definir seu alvo como foco, basta alterar a configuração de tecla (Teclas de atalho -> Seleção de alvo -> Focar o alvo). Se quiser também pode embutir a definição de foco em uma macro que lança um ataque qualquer; por exemplo, a macro abaixo lança Impacto Mental no seu alvo atual e define o alvo como foco, se não houver nenhum foco definido ou se o foco anterior já tiver morrido.

#showtooltip
/cast Impacto Mental
/focus [@focus,noexists,dead]

Esta macro lança Palavra Sombria: Morte no seu alvo, ou no foco se shift estiver pressionado:

#showtooltip
/cast [mod:shift,@focus,harm,nodead][] Palavra Sombria: Morte

Dá para incrementar ainda mais essa macro. Como Palavra Sombria: Morte gera mais insanidade se o alvo morrer com ela, pode ser que você queira usar em um add que você percebeu que está quase morrendo; neste caso você quer atacar o add apenas passando o mouse sobre ele, rapidamente, sem trocar de alvo nem foco. A macro abaixo ataca seu foco se shift estiver pressionado, caso contrário ataca o inimigo em quem o mouse estiver em cima, ou por fim ataca seu alvo mesmo.

#showtooltip
/cast [mod:shift,@focus,harm,nodead][@mouseover,harm,nodead][] Palavra Sombria: Morte

Com macros deste tipo você pode fazer coisas como por exemplo manter seu alvo em algum inimigo prioritário, mas deixando o chefe principal no foco e renovando os dots no chefe sem mudar de alvo, ou lançando Seta Caótica no chefe sem mudar de alvo, e assim por diante.

Por fim, lembre que seu foco também pode ser um aliado; você pode por exemplo manter um tank como foco e ter macros que lancem curas diretamente nele, sem precisar mudar de alvo.

Usando berloques em macros

Alguns berloques possuem efeitos que precisam ser ativados. Basta arrastar o ícone do berloque equipado para um botão na sua barra para usar. Se, porém, você preferir automatizar isso, você pode ter por exemplo uma macro que ativa o primeiro berloque:

/use 13

Se fosse o segundo berloque, o comando acima seria /use 14 (esses números correspondem ao item equipado no seu personagem; o elmo é o item 1 e assim por diante, até 13 e 14 para os berloques).

Pode ser que você queira usar o berloque ao mesmo tempo que uma habilidade sua. Digamos que você tenha um berloque cuja recarga é de 1 minuto, exatamente a mesma recarga que o Dobramentes, e você decida usar os dois juntos. A macro abaixo ativa o berloque e imediatamente depois lança Dobramentes. Dê preferência a usar o berloque antes em uma macro, porque ativar o berloque é uma ação instantânea que não ocupa um GCD (global cooldown).

#showtooltip
/use 13
/cast Dobramentes

Só que com essa macro o ícone que vai aparecer vai ser o ícone do berloque, porque é a primeira ação da macro. Se você quiser a mesma macro mas com o ícone do Dobramentes aparecendo, troque a primeira linha para #showtooltip Dobramentes

A macro abaixo ativa os dois berloques, a habilidade racial de trolls (Berserk), e depois começa a canalizar Hino Divino. A macro só funciona porque ativar os berloques e a habilidade racial são ações instantâneas que não ocupam um GCD (algumas habilidades raciais não ativam o GCD).

#showtooltip Hino Divino
/use 13
/use 14
/cast Berserk
/cast Hino Divino

Macro com talentos diferentes

Esta macro serve para Disciplina ou Sagrado, e usa Estrela Divina ou Halo conforme o talento escolhido. Se nenhum desses dois talentos foi escolhido no nível 90, o botão da macro irá mostrar uma interrogação vermelha e não fará nada. O parâmetro para a condição [talent:] é o seguinte: o primeiro número indica a linha do talento (os talentos nível 90 são a 6ª linha), e o segundo número é o número do talento naquela linha (por exemplo, Estrela Divina é o 2º talento).

#showtooltip
/cast [talent:6/2] Estrela Divina; [talent:6/3] Halo

 

Views: 96 desde outubro/2019.